Işıklandırma

Önceki bölümde, gerçekçi bir fizik tabanlı renderer kurmak için gereken temelleri attık. Bu bölümde, tartıştığımız teoriyi; nokta ışıklar, yönsel ışıklar ve/veya spot ışıkları gibi doğrudan (analitik) ışık kaynaklarını kullanan gerçek bir renderer'a dönüştürmeye odaklanacağız.

Önceki bölümdeki yansıma denklemini (reflectance equation) yeniden ele alalım:

$L_o(p,\omega_o) = \int\limits_{\Omega} \left(k_d\frac{c}{\pi} + \frac{DFG}{4(\omega_o \cdot n)(\omega_i \cdot n)}\right) L_i(p,\omega_i)\, n \cdot \omega_i\, d\omega_i$

Artık bu denklemin büyük bölümünü anlıyoruz; ancak hâlâ belirsizliğini koruyan soru şudur: Sahnenin toplam radyansını (L) nasıl temsil edeceğiz?

Radyans (L), bilgisayar grafiğinde yorumlandığı haliyle, bir ışık kaynağının belirli bir katı açı (ω) üzerindeki radyan akısını (φ) veya ışık enerjisini ölçer. Bizim durumumuzda katı açının sonsuz küçük olduğunu varsayıyoruz; bu durumda radyans, bir ışık kaynağının tek bir ışın yönündeki akısını ölçer.

Bu bilgiyi önceki bölümlerden öğrendiğimiz ışıklandırma bilgisiyle nasıl ilişkilendiririz? RGB değeri (23.47, 21.31, 20.79) olan, her yöne eşit parlaklıkta ışık yayan tek bir nokta ışığımız olduğunu düşünelim. Bu ışığın radyan yoğunluğu, tüm giden yön ışınlarındaki radyan akısına eşittir. Ancak belirli bir p noktasını gölgelerken, yüzeyin yarım küresi (Ω) üzerindeki olası gelen ışık yönlerinden yalnızca biri olan wᵢ, doğrudan bu nokta ışıktan gelir. Sahnede yalnızca tek bir ışık kaynağı olduğunu veya tek bir nokta olduğunu varsaydığımızdan, p noktasında sıfır olmayan radyans yalnızca bu bir ışın üzerindedir:

Nokta ışık kaynağında radyans

Başlangıçta ışık zayıflamasının (ışığın mesafeye göre kararması) nokta ışığı etkilemediğini varsayarsak, gelen ışının radyansı ışığı nereye yerleştirirsek yerleştirelim aynı kalır; yalnızca geliş açısı cos θ ile ölçeklenir. Çünkü nokta ışık hangi açıdan bakılırsa bakılsın aynı radyan yoğunluğuna sahiptir ve radyan yoğunluğunu sabit bir vektör ((23.47, 21.31, 20.79)) olarak modellemektedir.

Ancak radyans, girdi olarak p konumunu da alır ve herhangi bir gerçekçi nokta ışık zayıflamayı hesaba kattığından, radyan yoğunluğu p noktasıyla ışık kaynağı arasındaki mesafeye göre ölçeklenir. Ardından, orijinal radyans denkleminden çıkarıldığı üzere sonuç, yüzey normali n ile gelen ışın yönü wᵢ arasındaki nokta çarpımıyla da ölçeklenir.

Daha pratik bir ifadeyle: doğrudan bir nokta ışığı için radyans fonksiyonu L, ışık rengini ölçer, p'ye olan mesafeye göre zayıflatır ve n · wᵢ ile ölçekler — ancak yalnızca p'ye çarpan tek bir wᵢ ışın vektörü üzerinden. Kodda bu şöyle ifade edilir:

vec3  lightColor  = vec3(23.47, 21.31, 20.79);
vec3  wi          = normalize(lightPos - fragPos);
float cosTheta    = max(dot(N, wi), 0.0);
float attenuation = calculateAttenuation(fragPos, lightPos);
vec3  radiance    = lightColor * attenuation * cosTheta;

Farklı terminoloji bir yana, bu kod parçası size son derece tanıdık gelmeli: Şimdiye kadar diffuse ışıklandırma yaparken tam olarak bunu yapıyorduk. Doğrudan ışıklandırmada radyans, yüzeyin radyansına yalnızca tek bir ışık yönü katkıda bulunacağından, önceki hesaplamalarımızla aynı şekilde hesaplanır.

Not: Bu varsayım, nokta ışıkların uzayda sonsuz küçük ve tek bir nokta olduğu durumda geçerlidir. Alan veya hacme sahip bir ışık (area light) modellenecek olsaydı, radyans birden fazla gelen ışın yönünde sıfır olmazdı.

Tek bir noktadan kaynaklanan diğer ışık türleri için de radyansı benzer şekilde hesaplarız. Örneğin, yönsel bir ışık kaynağının (directional light) zayıflama faktörü olmaksızın sabit bir wᵢ vektörü vardır. Spot ışığının ise sabit bir radyan yoğunluğu olmayıp, ileri yön vektörüne göre ölçeklenen bir yoğunluğu vardır.

Bu da bizi yüzeyin yarım küresi (Ω) üzerindeki integral (∫) işaretine geri götürür. Tek bir yüzey noktasını gölgelerken katkıda bulunan tüm ışık kaynaklarının konumlarını önceden bildiğimizden, integrali sayısal olarak çözmemize gerek yoktur. Katkıda bulunan ışık sayısını (bilinen sayı) doğrudan hesaplayabilir ve toplam iradyansı bulabiliriz. Bu, PBR'ı doğrudan ışık kaynaklarında oldukça basitleştirir: pratikte yalnızca katkıda bulunan ışıklar üzerinde döngü kurmamız yeterlidir. IBL bölümlerinde çevre ışıklandırmasını hesaba kattığımızda ise ışık her yönden gelebileceğinden integrali gerçekten çözmemiz gerekecektir.

---

PBR Yüzey Modeli

Önce PBR modellerini uygulayan bir fragment shader yazalım. İlk olarak gerekli PBR girdilerini alıyoruz:

#version 330 core
out vec4 FragColor;
in vec2 TexCoords;
in vec3 WorldPos;
in vec3 Normal;
  
uniform vec3 camPos;
  
uniform vec3  albedo;
uniform float metallic;
uniform float roughness;
uniform float ao;

Standart girdileri jenerik bir vertex shader'dan ve nesnenin yüzeyi üzerindeki sabit malzeme özelliklerinden alıyoruz.

Ardından fragment shader'ın başlangıcında her ışıklandırma algoritmasında olduğu gibi gerekli hesaplamaları yapıyoruz:

void main()
{
    vec3 N = normalize(Normal); 
    vec3 V = normalize(camPos - WorldPos);
    [...]
}

Doğrudan Işıklandırma

Bu bölümün örnek demosunda toplam 4 nokta ışık var ve bunlar birlikte sahnenin iradyansını temsil ediyor. Yansıma denklemini karşılamak için her ışık kaynağı üzerinde döngü kurarak her birinin radyan katkısını hesaplıyor, BRDF ve geliş açısıyla ölçeklendirip topluyoruz. Bu döngüyü, doğrudan ışık kaynakları için Ω üzerindeki integrali sayısal olarak çözmek gibi düşünebiliriz. İlk olarak her ışık için ilgili değişkenleri hesaplıyoruz:

vec3 Lo = vec3(0.0);
for(int i = 0; i < 4; ++i) 
{
    vec3 L = normalize(lightPositions[i] - WorldPos);
    vec3 H = normalize(V + L);
  
    float distance    = length(lightPositions[i] - WorldPos);
    float attenuation = 1.0 / (distance * distance);
    vec3 radiance     = lightColors[i] * attenuation; 
    [...]  

Hesaplamalar linear uzayda yapıldığından (shader'ın sonunda gamma düzeltmesi uygulayacağız), ışık kaynaklarını fiziksel olarak daha doğru olan ters kare yasasıyla (inverse-square law) zayıflatıyoruz.

Fiziksel olarak doğru olmasa da, sabit-doğrusal-kuadratik zayıflama denklemini kullanmak isteyebilirsiniz; bu denklem ışığın enerji düşüşü üzerinde çok daha fazla kontrol sağlar.

Ardından her ışık için tam Cook-Torrance specular BRDF terimini hesaplamak istiyoruz:

$\frac{DFG}{4(\omega_o \cdot n)(\omega_i \cdot n)}$

Yapmak istediğimiz ilk şey specular ile diffuse yansıma arasındaki oranı hesaplamaktır; yani yüzeyin ışığı ne kadar yansıttığına karşın ne kadar kırdığını bulmaktır. Önceki bölümden bildiğimiz gibi Fresnel denklemi tam olarak bunu hesaplar (clamp kullandığımıza dikkat edin — siyah noktaları önlemek için):

vec3 fresnelSchlick(float cosTheta, vec3 F0)
{
    return F0 + (1.0 - F0) * pow(clamp(1.0 - cosTheta, 0.0, 1.0), 5.0);
}

Fresnel-Schlick yaklaşımı, sıfır açısında yüzey yansıması olarak bilinen bir F0 parametresi bekler. Bu değer, yüzeye doğrudan bakıldığında malzemenin ne kadar yansıttığını temsil eder. F0 malzemeye göre değişir ve büyük malzeme veritabanlarında bulunabilir. PBR metallic workflow'da çoğu dielektrik yüzeyin F0 = 0.04 ile görsel olarak doğru sonuç verdiği basitleştirmesini yapıyoruz; metalik yüzeyler için ise F0 albedo değeriyle belirlenir. Kod olarak:

vec3 F0 = vec3(0.04); 
F0      = mix(F0, albedo, metallic);
vec3 F  = fresnelSchlick(max(dot(H, V), 0.0), F0);

Gördüğünüz gibi metalik olmayan yüzeyler için F0 her zaman 0.04'tür. Metalik yüzeyler için ise metallic özelliğine bağlı olarak orijinal F0 ile albedo arasında doğrusal interpolasyon yapılır.

F elde edildikten sonra kalan terimler Normal Dağılım Fonksiyonu (D) ve Geometri Fonksiyonu (G)'dir.

Doğrudan PBR ışıklandırma shader'ındaki kod karşılıkları:

float DistributionGGX(vec3 N, vec3 H, float roughness)
{
    float a      = roughness*roughness;
    float a2     = a*a;
    float NdotH  = max(dot(N, H), 0.0);
    float NdotH2 = NdotH*NdotH;
	
    float num   = a2;
    float denom = (NdotH2 * (a2 - 1.0) + 1.0);
    denom = PI * denom * denom;
	
    return num / denom;
}

float GeometrySchlickGGX(float NdotV, float roughness)
{
    float r = (roughness + 1.0);
    float k = (r*r) / 8.0;

    float num   = NdotV;
    float denom = NdotV * (1.0 - k) + k;
	
    return num / denom;
}

float GeometrySmith(vec3 N, vec3 V, vec3 L, float roughness)
{
    float NdotV = max(dot(N, V), 0.0);
    float NdotL = max(dot(N, L), 0.0);
    float ggx2  = GeometrySchlickGGX(NdotV, roughness);
    float ggx1  = GeometrySchlickGGX(NdotL, roughness);
	
    return ggx1 * ggx2;
}

Burada önemli bir nokta: Teori bölümünün aksine, roughness parametresini doğrudan bu fonksiyonlara geçiriyoruz; böylece orijinal roughness değeri üzerinde terime özgü değişiklikler yapabiliyoruz. Disney'in gözlemlerine ve Epic Games'in benimsemesine göre, geometry ve NDF fonksiyonlarında roughness'ı kare alarak kullanmak ışıklamayı görsel olarak daha doğru hale getiriyor.

Her iki fonksiyon da tanımlandığına göre yansıma döngüsü içinde NDF ve G terimini hesaplamak artık kolaydır:

float NDF = DistributionGGX(N, H, roughness);       
float G   = GeometrySmith(N, V, L, roughness);       

Bu Cook-Torrance BRDF'yi hesaplamak için yeterlidir:

vec3 numerator    = NDF * G * F;
float denominator = 4.0 * max(dot(N, V), 0.0) * max(dot(N, L), 0.0) + 0.0001;
vec3 specular     = numerator / denominator;

Herhangi bir nokta çarpımının 0.0 olması durumunda sıfıra bölünmeyi önlemek için paydaya 0.0001 ekliyoruz.

Artık her ışığın yansıma denklemine olan katkısını hesaplayabiliriz. Fresnel değeri doğrudan kS'e karşılık geldiğinden, F değişkenini yüzeye çarpan herhangi bir ışığın specular katkısını göstermek için kullanabiliriz. kS'ten kırılma oranını kD olarak hesaplayabiliriz:

vec3 kS = F;
vec3 kD = vec3(1.0) - kS;
  
kD *= 1.0 - metallic;

kS yansıyan enerjiyi temsil ettiğinden, kalan ışık enerjisi oranı kD olur. Ayrıca metalik yüzeyler ışığı kırmadığından ve dolayısıyla diffuse yansıması olmadığından, yüzey metalikse kD'yi sıfıra indiriyoruz. Bu sayede her ışığın giden radyans değerini hesaplamak için gereken son verilere sahibiz:

    const float PI = 3.14159265359;
  
    float NdotL = max(dot(N, L), 0.0);        
    Lo += (kD * albedo / PI + specular) * radiance * NdotL;
}

Elde edilen Lo değeri ya da giden radyans, pratikte yansıma denkleminin Ω üzerindeki integrali (∫) için bir yaklaşımdır. Tam olarak katkıda bulunan 4 gelen ışın yönünü bildiğimizden integrali çözmeye gerek yoktur; bu 4 ışın yönü üzerinden, yani sahnedeki ışık sayısı kadar doğrudan döngü kurabiliriz.

Geriye kalan, doğrudan ışıklandırma sonucu Lo'ya (hazır olmayan) bir ambient terimi ekleyerek fragment'ın son renklendirilmiş rengini bulmaktır:

vec3 ambient = vec3(0.03) * albedo * ao;
vec3 color   = ambient + Lo;

Linear ve HDR Rendering

Tüm hesaplamalarımızın linear renk uzayında yapıldığını varsaydık; bunu hesaba katmak için shader'ın sonunda gamma düzeltmesi yapmamız gerekiyor. Linear uzayda ışıklandırma hesaplaması PBR için son derece önemlidir — tüm girdilerin linear olması zorunludur, aksi hâlde ışıklandırma yanlış çıkar. Buna ek olarak, ışık girdilerinin fiziksel karşılıklarına yakın olmasını istiyoruz; bu nedenle radyans veya renk değerleri geniş bir aralıkta büyük değerlere ulaşabilir. Sonuç olarak Lo, LDR (düşük dinamik aralık) çıktısı nedeniyle 0.0 ile 1.0 arasına sıkışmadan önce hızla büyük değerlere ulaşabilir. Bunu düzeltmek için gamma düzeltmesinden önce Lo'yu ton eşleme (tonemapping) ya da pozlama eşlemesiyle HDR değerini LDR'ye doğru şekilde dönüştürüyoruz:

color = color / (color + vec3(1.0));
color = pow(color, vec3(1.0/2.2)); 

Burada HDR rengi, olası yüksek dinamik aralıklı iradyansı koruyarak Reinhard operatörüyle ton eşliyoruz; ardından gamma düzeltmesini uyguluyoruz. Ayrı bir framebuffer veya post-processing aşamamız olmadığından, her iki adımı doğrudan ileri fragment shader'ın sonunda uygulayabiliyoruz.

Linear ve HDR rendering karşılaştırması

Linear renk uzayını ve HDR'yi hesaba katmak PBR pipeline'ında son derece önemlidir. Bu adımlar olmadan, farklı ışık yoğunluklarının yüksek ve düşük detaylarını doğru yakalamak mümkün değildir; hesaplamalar yanlış ve dolayısıyla görsel olarak tatmin edici olmayan sonuçlar üretir.

Tam Doğrudan Işıklandırma PBR Shader'ı

Geriye kalan tek şey, son ton eşlenmiş ve gamma düzeltilmiş rengi fragment shader'ın çıkış kanalına geçirmektir. İşte doğrudan PBR ışıklandırma shader'ının tamamı:

#version 330 core
out vec4 FragColor;
in vec2 TexCoords;
in vec3 WorldPos;
in vec3 Normal;

// malzeme parametreleri
uniform vec3  albedo;
uniform float metallic;
uniform float roughness;
uniform float ao;

// ışıklar
uniform vec3 lightPositions[4];
uniform vec3 lightColors[4];

uniform vec3 camPos;

const float PI = 3.14159265359;
  
float DistributionGGX(vec3 N, vec3 H, float roughness);
float GeometrySchlickGGX(float NdotV, float roughness);
float GeometrySmith(vec3 N, vec3 V, vec3 L, float roughness);
vec3 fresnelSchlick(float cosTheta, vec3 F0);

void main()
{		
    vec3 N = normalize(Normal);
    vec3 V = normalize(camPos - WorldPos);

    vec3 F0 = vec3(0.04); 
    F0 = mix(F0, albedo, metallic);
	           
    // yansıma denklemi
    vec3 Lo = vec3(0.0);
    for(int i = 0; i < 4; ++i) 
    {
        // her ışık için radyansı hesapla
        vec3 L = normalize(lightPositions[i] - WorldPos);
        vec3 H = normalize(V + L);
        float distance    = length(lightPositions[i] - WorldPos);
        float attenuation = 1.0 / (distance * distance);
        vec3 radiance     = lightColors[i] * attenuation;        
        
        // cook-torrance brdf
        float NDF = DistributionGGX(N, H, roughness);        
        float G   = GeometrySmith(N, V, L, roughness);      
        vec3 F    = fresnelSchlick(max(dot(H, V), 0.0), F0);       
        
        vec3 kS = F;
        vec3 kD = vec3(1.0) - kS;
        kD *= 1.0 - metallic;	  
        
        vec3 numerator    = NDF * G * F;
        float denominator = 4.0 * max(dot(N, V), 0.0) * max(dot(N, L), 0.0) + 0.0001;
        vec3 specular     = numerator / denominator;  
            
        // giden radyans Lo'ya ekle
        float NdotL = max(dot(N, L), 0.0);                
        Lo += (kD * albedo / PI + specular) * radiance * NdotL; 
    }   
  
    vec3 ambient = vec3(0.03) * albedo * ao;
    vec3 color = ambient + Lo;
	
    color = color / (color + vec3(1.0));
    color = pow(color, vec3(1.0/2.2));  
   
    FragColor = vec4(color, 1.0);
}  

Umarım Teori bölümündeki bilgiler ve yansıma denklemi üzerine edinilenler sayesinde bu shader artık o kadar da korkutucu gelmiyordur. Bu shader'ı, 4 nokta ışık ve metallic ile roughness değerlerini sırasıyla dikey ve yatay eksende değiştirdiğimiz bir küre seti ile kullanırsak şöyle bir sonuç elde ederiz:

PBR küreleri — roughness ve metallic değerleri değiştirilerek

Aşağıdan yukarıya metallic değeri 0.0'dan 1.0'a, soldan sağa roughness değeri 0.0'dan 1.0'a artmaktadır. Bu iki basit parametreyi değiştirerek bile birbirinden farklı geniş bir malzeme yelpazesi gösterebildiğimize dikkat edin.

Demo'nun tam kaynak kodunu buradan bulabilirsiniz.

---

Dokulu PBR (Textured PBR)

Sistemi uniform değerler yerine dokuları (texture) kabul edecek şekilde genişletmek, yüzey malzemesinin özellikleri üzerinde fragment başına kontrol sahibi olmamızı sağlar:

[...]
uniform sampler2D albedoMap;
uniform sampler2D normalMap;
uniform sampler2D metallicMap;
uniform sampler2D roughnessMap;
uniform sampler2D aoMap;
  
void main()
{
    vec3 albedo     = pow(texture(albedoMap, TexCoords).rgb, 2.2);
    vec3 normal     = getNormalFromNormalMap();
    float metallic  = texture(metallicMap, TexCoords).r;
    float roughness = texture(roughnessMap, TexCoords).r;
    float ao        = texture(aoMap, TexCoords).r;
    [...]
}

Sanatçılardan gelen albedo dokularının genellikle sRGB uzayında oluşturulduğunu; bu nedenle ışıklandırma hesaplamalarında kullanmadan önce bunları pow(..., 2.2) ifadesiyle linear alana dönüştürmemiz gerektiğini unutmayın. Ambient occlusion haritaları için kullanılan sisteme bağlı olarak bunları da sRGB'den linear alana dönüştürmeniz gerekebilir. Metallic ve roughness haritaları ise neredeyse her zaman linear uzayda oluşturulur.

Önceki küre setinin malzeme özelliklerini dokularla değiştirmek, daha önce kullandığımız ışıklandırma algoritmalarına kıyasla büyük bir görsel iyileşme sağlar:

Dokulu PBR küreleri

Dokulu demonun tam kaynak kodunu buradan ve kullanılan doku setini buradan bulabilirsiniz (beyaz bir ao haritasıyla birlikte). Metalik yüzeylerin doğrudan ışıklandırma ortamlarında çok karanlık görünme eğiliminde olduğunu unutmayın; diffuse yansıması olmadığından bu beklenen bir durumdur. Çevre specular ambient ışıklandırması hesaba katıldığında çok daha doğru görüneceklerdir; buna bir sonraki bölümlerde odaklanacağız.

Dışarıda gördüğünüz bazı PBR render demolarıyla kıyaslandığında bu görsel sonuç o kadar etkileyici olmayabilir — henüz görüntü tabanlı ışıklandırma (IBL) entegre etmedik. Bununla birlikte, sahip olduğumuz sistem gerçek anlamda fizik tabanlı bir renderer'dır ve IBL olmaksızın bile ışıklandırmanın çok daha gerçekçi göründüğünü fark edeceksiniz.

---

Orijinal kaynak: LearnOpenGL – PBR/Lighting Türkçe çeviri: Nezihe Sözen